set ampm autolist color colorcat complete = enhance ellipsis
set fignore = (.o .pyc .pyo \~)
set histlit histdup = erase
set time = 5 ignoreeof = 10 implicitcd inputmode = insert
set echo_style = both
set killring = 30 listjobs = long symlinks = chase
#set printexitvalue <-- done last to avoid spurious errors.
set rmstar recognize_only_executables nobeep noclobber nonomatch
unset autologout notify


# keyboard
test -t 0
if (! $status) then
    bindkey ' ' magic-space
    bindkey '^Z' run-fg-editor
    bindkey -c '\e^Z' 'fg %-'
    bindkey '\e[5~' complete-word-back
    bindkey '\e[6~' complete-word-fwd
    bindkey '\e[3~' delete-char
    bindkey '\e\e[3~' delete-word
    bindkey '\e[3;3~' delete-word
    bindkey '\e^H' backward-delete-word
    bindkey '\e^?' backward-delete-word
    bindkey '^R' i-search-back
    bindkey '^S' i-search-fwd
    bindkey '\e[2~' overwrite-mode
    bindkey '\e[1~' beginning-of-line
    bindkey '\e[4~' end-of-line
    bindkey '\e\e[D' backward-word
    bindkey '\e[3D' backward-word
    bindkey '\e[1;3D' backward-word
    bindkey '\e\e[C' forward-word
    bindkey '\e[3C' forward-word
    bindkey '\e[1;3C' forward-word
    bindkey '\e*' expand-glob

    # whoever came up with these needs to be kicked
    bindkey -r '^S'
    bindkey -r '^Q'
    stty start '' stop ''
endif


# options/aliases for ls
# see also LSCOLORS in .login
unsetenv LS_OPTIONS
test `uname` = 'Linux'
if ($status) then
    set LS_OPTIONS = '-BFGh'
else
    set LS_OPTIONS = '-BFNv -I "*.o" --color=always'
endif

alias ls '/bin/ls $LS_OPTIONS'
alias dir '/bin/ls $LS_OPTIONS -C'
alias vdir '/bin/ls $LS_OPTIONS -l'
alias d dir
alias v vdir

alias . "source"
alias - "cd -"
set owd = "`pwd`"

alias mkdir "mkdir -p"
alias md "mkdir"
alias rd "rmdir"
alias q "exit"
alias grep "grep -irn"
alias clh "history -c"
alias cls "history -c; clear"
alias mv "mv -i"
alias cp "cp -i"
# rm -I doesn't work on os x
if (! -e /mach) alias rm "rm -I"
alias df "df -h"
alias l "less"
alias s "screen"

alias y "yaourt"

alias cal "cal -3"

if (-e /Developer/Applications/Xcode.app) alias xcode "open -a xcode"
if (-e /usr/bin/gnome-open) alias open gnome-open
if (-e /usr/bin/exo-open) alias open exo-open
#if (-e /usr/bin/elvis || -e /usr/bin/elvis) alias vi elvis

alias calc "python -c 'print \!*'"
alias length 'echo -n "\!*"|wc -c'

alias helpcommand "\!* --help"

# I don't like tcsh's builtin nice. Don't remember why.
alias nice /usr/bin/nice

# "Fix" my spellnig errosr, so I can MASH BUTANS and still look productive.
alias maek make
alias mkae make
alias amek make
alias amke make
alias gf fg
alias jbos jobs

set prompt = '%B[%b%n@%m%B:%b%l%B]%b %d %D %w %Y %t\n[%h] %c03%B%#%b '


complete unalias	'p/*/a/'
complete unset		'p/*/s/'
complete unsetenv	'p/*/e/'
complete {un,}complete	'p/*/X/'
complete limit		'p/1/l/'
complete env		'n/-u/e/'
complete -%*		'c/*/j/'
complete {fg,bg}	'c/%/j/' 'p/*/(%)//'
complete kill		'c/-/S/' 'p/*/`ps h U $user -o pid`/'
complete killall	'c/-/S/' 'p/*/c/'
complete man		'c=./=f:*.[123456789nlpo]{,.gz,.bz2}=' 'p/*/c/'
complete dd		'c/*=/f/'
complete *-config	'c/--/(bindir cflags datadir exec-prefix help includedir infodir libdir libexecdir libs libs-only-L libs-only-l localstatedir mandir modversion prefix sbindir sharedstatedir sysconfdir version)/'
complete finger		'c~*@~`sed -n "s/^[0-9.]*//;/^[^#]/p" /etc/hosts`~' 'p/*/u//'
complete info		'p~*~`(/bin/ls /usr/share/info; /bin/ls /usr/local/share/info) | sed '\''s/\.info.*$//;s/[-.][0-9].\+$/\1/;s/\.gz$//'\'' | sort | uniq`~'
complete fortune	'p~*~`(cd /usr/share/games/fortunes && /bin/ls *.dat off/*.dat) | sed s/.dat\$//`~'

complete {cd,rd,{ch,rm}dir} 'p/*/d/'
complete {w,su,write,*talk} 'p/*/u/'
complete {gdb,exec,sudo,fork,time} 'p/1/c/' 'p/*/f/'
complete {{,v,f}which,whereis,whatis,killall,pidof} 'p/*/c/'
complete {ping,telnet,ssh,traceroute,host} 'p~*~`sed -n "s/^[0-9.]*//;/^[^#]/p" /etc/hosts`~'

complete {ls,dir,vdir,v,d} \
    'c/--/(all almost-all color classify dereference dereference-command-line directory dired escape file-type full-time format help hide-control-chars ignore ignore-backups indicator-style inode kilobytes literal no-group numeric-uid-gid quote-name quoting-style recursive reverse size sort tabsize time time-style version width)/' \
    'c/--format=/(long verbose commas across vertical single-column)/' \
    'n/--format/(long verbose commas across vertical single-column)/' \
    'c/--sort=/(none size time extension status atime access use version)/' \
    'n/--sort/(none size time extension status atime access use version)/' \
    'c/--time=/(atime access use ctime status)/' \
    'n/--time/(atime access use ctime status)/' \
    'c/--time-style=/(full-iso iso locale posix-iso)/' \
    'n/--time-style/(full-iso iso locale posix-iso)/' \
    'c/--quoting-style=/(literal locale shell shell-always c escape)/' \
    'n/--quoting-style/(literal locale shell shell-always c escape)/' \
    'c/--indicator-style=/(none classify file-type)/' \
    'n/--indicator-style/(none classify file-type)/' \
    'c/--color=/(none auto always)/'
complete find \
    'c/-/(daystart depth follow help -help maxdepth mindepth mount noleaf version -version xdev amin anewer atime cmin cnewer ctime empty false fstype gid group ilname iname inum ipath iregex links lname mmin mtime name newer nouser nogroup path perm regex size true type uid used user xtype exec fls fprint fprint0 fprintf ok print print0 printf prune ls not a and o or)/' \
    'n/-{{a,c,}newer,f{ls,print{,0,f}}}/f/' \
    'n/-{exec,ok}/c/' \
    'n/-fstype/(ext2 proc devpts vfat iso9660)/' \
    'n~-gid~`cut -d: -f3 < /etc/group`~' \
    'n~-group~`cut -d: -f1,3 --output-delimiter=" " < /etc/group`~' \
    'n/-{,x}type/(b c d p f l s)/' \
    'n~-uid~`cut -d: -f3 < /etc/passwd`~' \
    'n~-user~`cut -d: -f1,3 --output-delimiter=" " < /etc/passwd`~' \
    'p/1/d/'


# i can never remember the options for imagemagick apps

complete animate \
    'c/{+,-}/(backdrop cache colormap colors colorspace crop delay density display dither gamma geometry interlace map monochrome remote rotate scene size title treedepth verbose visual window background bordercolor borderwidth font foreground iconGeometry iconic mattecolor name)/' \
    'n/-colormap/(shared private)/' \
    'n/-colorspace/(gray ohta rgb transparent xyz ycbcr yiq ypbpr yuv cmyk)/' \
    'n/-interlace/(none line plane partition)/' \
    'n/-map/(best default gray red green blue)/' \
    'n/-visual/(staticgray grayscale staticcolor pseudocolor truecolor directcolor default)/' \
    'n/-window/(root)/' \
    'n/-{background,bordercolor,foreground,mattecolor}/`tail +2 < $x11_rgbfile | expand | sed "s,^[0-9 ]*,,;s, ,,g" | tr A-Z a-z | sort | uniq`/' \
    'c/@/f/'
complete combine \
    'c/{+,-}/(blend cache colors colorspace comment compose compress density displace dither font geometry gravity interlace label matte monochrome negate page quality scene size stegano stereo tile treedepth verbose)/' \
    'n/-colorspace/(gray ohta rgb transparent xyz ycbcr yiq ypbpr yuv cmyk)/' \
    'n/-compose/(over in out atop xor plus minus add subtract difference bumpmap replace replacered replacegreen replaceblue replacematte)/' \
    'n/-compress/(none bzip fax group4 jpeg lzw runlengthencoded zip)/' \
    'n/-interlace/(none line plane partition)/' \
    'c/@/f/'
complete convert \
    'c/{+,-}/(adjoin antialias append average blur border bordercolor box cache charcoal coalesce colorize colors colorspace comment compress contrast crop cycle deconstruct delay density depth despeckle display dispose dither draw edge emboss enhance equalize filter flip flop font frame fuzz gamma geometry gravity implode interlace label layer linewidth loop map matte median modulate monochrome morph mosaic negate noise normalize opaque page paint pen pointsize preview profile quality raise region roll rotate sample scene seed segment shade sharpen shear size solarize spread swirl texture threshold transparency treedepth units verbose view wave)/' \
    'n/-colorspace/(gray ohta rgb transparent xyz ycbcr yiq ypbpr yuv cmyk)/' \
    'n/-compress/(none bzip fax group4 jpeg lzw runlengthencoded zip)/' \
    'n/-filter/(point box triangle hermite hanning hamming blackman gaussian quadratic cubic catrom mitchell lanczos bessel sinc)/' \
    'n/-interlace/(none line plane partition)/' \
    'n/-layer/(red green blue matte)/' \
    'n/+noise/(uniform gaussian multiplicative impulse laplacian poisson)/' \
    'n/-preview/(rotate shear roll hue saturation brightness gamma spiff dull grayscale quantize despeckle reducenoise addnoise sharpen blur threshold edgedetect spread shade raise segment solarize swirl implode wave oilpaint charcoaldrawing jpeg)/' \
    'n/-{bordercolor,box,opaque,pen,transparency}/`tail +2 < $x11_rgbfile | expand | sed "s,^[0-9 ]*,,;s, ,,g" | tr A-Z a-z | sort | uniq`/' \
    'c/@/f/'
complete display \
    'c/{+,-}/(backdrop border cache colormap colors colorspace comment compress contrast crop delay density despeckle display dispose dither edge enhance filter flip flop frame gamma geometry help interlace immutable label map matte monochrome negate page quality raise remote roll rotate sample scene segment sharpen size texture title treedepth update verbose visual window write background bordercolor borderwidth font foreground iconGeometry iconic mattecolor name)/' \
    'n/-colormap/(shared private)/' \
    'n/-colorspace/(gray ohta rgb transparent xyz ycbcr yiq ypbpr yuv cmyk)/' \
    'n/-compress/(none bzip fax group4 jpeg lzw runlengthencoded zip)/' \
    'n/-filter/(point box triangle hermite hanning hamming blackman gaussian quadratic cubic catrom mitchell lanczos bessel sinc)/' \
    'n/-interlace/(none line plane partition)/' \
    'n/-map/(best default gray red green blue)/' \
    'n/-visual/(staticgray grayscale staticcolor pseudocolor truecolor directcolor default)/' \
    'n/-window/(root)/' \
    'n/-{background,bordercolor,foreground,mattecolor}/`tail +2 < $x11_rgbfile | expand | sed "s,^[0-9 ]*,,;s, ,,g" | tr A-Z a-z | sort | uniq`/' \
    'c/@/f/'
complete import \
    'c/{+,-}/(adjoin border cache colorspace comment compress crop delay density descend display dispose dither frame geometry interlace label monochrome negate page pointsize quality rotate scene screen silent transparency treedepth verbose window background bordercolor borderwidth font foreground iconGeometry iconic mattecolor name)/' \
    'n/-colorspace/(gray ohta rgb transparent xyz ycbcr yiq ypbpr yuv cmyk)/' \
    'n/-compress/(none bzip fax group4 jpeg lzw runlengthencoded zip)/' \
    'n/-interlace/(none line plane partition)/' \
    'n/-{background,bordercolor,foreground,mattecolor,transparency}/`tail +2 < $x11_rgbfile | expand | sed "s,^[0-9 ]*,,;s, ,,g" | tr A-Z a-z | sort | uniq`/' \
    'n/-window/(root)/' \
    'c/@/f/'
complete make \
    'c/-{C,I,-directory=,-include-dir=}/d/' \
    'c/-{W,o,f,-what-if=,-{new,old}-file=,-assume-{new,old}=,-file=,-makefile=}/f/' \
    'c/--/(directory debug environment-overrides file makefile help ignore-errors include-dir jobs keep-going load-average max-load just-print dry-run recon old-file assume-old print-data-base question no-builtin-rules no-builtin-variables silent quiet no-keep-going stop touch version print-directory no-print-directory what-if new-file assume-new warn-undefined-variables)/' \
    'c/-/(C e f h i I j k l n o p q r R s S t v w W -)/' \
    'n/-{C,I,-directory,-include-dir}/d/' \
    'n/-{W,o,f,-what-if,-{new,old}-file,-assume-{new,old},-file,-makefile}/f/' \
    'p/*/`grep -s "^[A-Za-z0-9_-][A-Za-z0-9_.-]*:" Makefile | cut -d: -f1 | sort | uniq`/'
complete mogrify \
    'c/{+,-}/(antialias blur border bordercolor box cache charcoal colorize colors colorspace comment compress contrast crop cycle delay density depth despeckle display dispose dither draw edge emboss enhance equalize filter flip flop format font frame fuzz gamma geometry gravity implode interlace layer linewidth loop map matte median modulate monochrome negate noise normalize opaque page paint pen pointsize quality raise region roll rotate sample scene seed segment shade sharpen shear size solarize spread swirl texture threshold transparency treedepth units verbose view wave)/' \
    'n/-colorspace/(gray ohta rgb transparent xyz ycbcr yiq ypbpr yuv cmyk)/' \
    'n/-compress/(none bzip fax group4 jpeg lzw runlengthencoded zip)/' \
    'n/-filter/(point box triangle hermite hanning hamming blackman gaussian quadratic cubic catrom mitchell lanczos bessel sinc)/' \
    'n/-interlace/(none line plane partition)/' \
    'n/-layer/(red green blue matte)/' \
    'n/+noise/(uniform gaussian multiplicative impulse laplacian poisson)/' \
    'n/-{bordercolor,box,opaque,pen,transparency}/`tail +2 < $x11_rgbfile | expand | sed "s,^[0-9 ]*,,;s, ,,g" | tr A-Z a-z | sort | uniq`/' \
    'n/-format/(avs bie bmp bmp24 cgm cmyk dcx dib dicom epdf epi eps eps2 epsf epsi ept fax fig fits fpx gif gif87 gray hdf histogram hpgl html jbig jpeg ico label map miff mono mpeg mtv pbm pcd pcl pcx pdf pgm pict pix png pnm ppm ps psd ps2 p7 rad rgb rgba rla rle sgi shtml sun text tga tiff tiff24 tile tim uil uvuy vid viff xbm xpm xwd yuv)/' \
    'c/@/f/'
complete montage \
    'c/{+,-}/(adjoin blur cache colors colorspace comment compose compress crop density display dispose dither draw filter frame font gamma geometry gravity interlace label matte mode monochrome page pen pointsize quality rotate scene shadow sharpen size texture tile transparency treedepth verbose background bordercolor borderwidth foreground mattecolor title)/' \
    'n/-colorspace/(gray ohta rgb transparent xyz ycbcr yiq ypbpr yuv cmyk)/' \
    'n/-compose/(over in out atop xor plus minus add subtract difference bumpmap replace replacered replacegreen replaceblue replacematte)/' \
    'n/-compress/(none bzip fax group4 jpeg lzw runlengthencoded zip)/' \
    'n/-filter/(point box triangle hermite hanning hamming blackman gaussian quadratic cubic catrom mitchell lanczos bessel sinc)/' \
    'n/-interlace/(none line plane partition)/' \
    'n/-mode/(frame unframe concatenate)/' \
    'n/-{background,bordercolor,foreground,mattecolor,transparency,pen}/`tail +2 < $x11_rgbfile | expand | sed "s,^[0-9 ]*,,;s, ,,g" | tr A-Z a-z | sort | uniq`/' \
    'c/@/f/'

# -------------------------------------------------------------------------

set printexitvalue